「ベクトルを使ってみよう」を参考にして、キーボードでは動作させる事ができたのですが、
マウスでクリックした地点に、キャラクターを（等速で）移動させるにはどうすればよいでしょうか。
宜しくお願いします。

等速であればこんな感じでしょうか。


// パラメータ
var SPEED_MAX = 10;// 最高速度

// 背景
var bg : Shape = new Shape();
bg.graphics.beginFill(0xFFC0C0);
bg.graphics.drawRect(0,0,stage.stageWidth,stage.stageHeight);
bg.graphics.endFill();
addChild(bg);

// プレイヤー
var player : Sprite = new Sprite();
player.graphics.beginFill(0x4040F0);
player.graphics.drawRect(-20,-20,40,40);
player.graphics.endFill();
addChild(player);


// 位置
var pos : Point = new Point(100,100);
// 速度
var spd : Point = new Point(0,0);
// ターゲット
var target : Point = new Point(300,300);

// クリックされたらターゲットをマウスの位置に更新
stage.addEventListener(MouseEvent.MOUSE_DOWN,function(e:MouseEvent){
target.x = stage.mouseX;
target.y = stage.mouseY;

});

// 毎フレーム処理
addEventListener(Event.ENTER_FRAME,function(e:Event){

// 座標からターゲットまでのベクトル
var v : Point = target.subtract(pos);

// ターゲットまでの距離
var d : Number = v.length;

// 距離が最高速度を超えるかチェック
if(d > SPEED_MAX)d = SPEED_MAX;

// 正規化してから拡大
v.normalize(d);

// 速度に反映
spd.x = v.x;
spd.y = v.y;

// 座標に速度を加算
pos = pos.add(spd);

// 座標を player に反映
player.x = pos.x;
player.y = pos.y;
});

助かりました
ありがとうございます！